@echo off
rem ... The "subroutine batch" called from main batch DEMOTEX.BAT
if "%1==" goto end
echo This is TeX-menu-system, Version Jan-30-1993 (for DOS)
rem =========== system dependent values ===============
set TEXDIR=.
set TEXDIRCFG=.
set RAM=.
set EDIT=echo RUN editor
set SHELL=c:\nc\nc
set TEXVER=tex
set SCROPT=/oi-
set EMTEXED=echo RUN editor %%2 %%3 -n%%1
set SPELLOPT=@K
set INDEXOPT=-z keybcs2
set BIBTEXOPT=/k
set KBD=rem
set TMP=.
rem ===================================================
set VLNKA=KkOoUuVvSsZzAI
set DVIDRV=/pr:{,$TEXDIRCFG:\}@f
set TEXCONFIG=%TEXDIRCFG%
set ERRCOM=call %RAM%\errbat
set USERCOM=call bat.bat
set LASTCOM=echo ...... End of TeX system, bye !
set GFOPT=gftopk %%MF%%.180 %%MF%%.pk
set FMT=%1
set FFMT=%2
set WORK=%3
set MAIN=%3
if not "%4" == "" set WORK=%4
set MF=%MAIN%
set PATH=%TEXDIR%;%PATH%
set TEXFMT=%TEXDIR%\texfmts;.
set BTEXFMT=%TEXDIR%\btexfmts;.
set TEXTFM=%TEXDIR%\tfm;.
set TEXINPUT=%TEXDIR%\texinput;.
if %FMT%==INIT %TEXDIRCFG%\inibat
set MFBAS=%TEXDIR%\mfbases;.
set BMFBAS=%TEXDIR%\bmfbases;.
set MFINPUT=%TEXDIR%\mfinput;.
set MFJOB=%TEXDIR%\mfjob
set OUTHP=lpt1
set OUT24=lpt1
set OUT9=lpt1
set DPI24=180
set MNU=31
if "%WORK%"=="" set MNU=121

if exist %RAM%\texbat.bat goto start
rem ............................... copy frequently used files to RAM disk
mkdir %RAM%
copy %TEXDIRCFG%\ram\*.* %RAM% > nul
rem ............................... message + user-configuration
:start
if exist %TEXDIR%\cfg\message.txt type %TEXDIR%\cfg\message.txt
if exist texcfg.bat call texcfg
rem ............................... system keyboard driver + START!
%KBD% %TEXDIR%\kbd /yy
if not exist %RAM%\texbat.bat goto diskful
%RAM%\texbat
rem ............................... remove temporary files
if %RAM%==%TEXDIR%\cfg\ram goto end
for %%t in (%RAM%\*.*) do del %%t
rmdir %RAM%
goto end

:diskful
echo Disk full or no exists the %RAM% ! ?
%KBD% %TEXDIR%\kbd /u
:end